DEFGANTT

DesktopWebMobile

Consente di definire un diagramma di Gantt.

La fonte dati del controllo è una collezione di tipo BC_VID_GANTT.
Al suo interno, per ogni elemento, sono presenti le collezioni:

• BC_VID_GANT_LINK (Collegamenti tra task)
• BC_VID_GANTT_MARKER (Marcatori temporali)
• BC_VID_GANTT_RES (Risorse associate al task)
• BC_VID_GANTT_SUBTASK (Subtask del task principale).

L'aggiunta e l'eliminazione di un elemento all'interno della classe BC_VID_GANTT si rifletterà automaticamente sull'oggetto grafico, contrariamente alla modifica di una proprietà specifica. Data la complessità dell'oggetto la modifica della proprietà è stata delegata al metodo specifico UPDATETASKS.

suggerimento

Nel caso in cui si debbano eseguire modifiche massive è possibile sospende l'aggiornamento del controllo video tramite la specifica '@SUSPENDEDVIDREFRESH.

note

A partire dalla versione 28.5 è possibile associare il controllo grafico ad una griglia da collezione, creando così un controllo grafico composito.

Parametri

Parametro	Definizione	I/O		Versione traduttore	SMP
NOME	Intero
RET
POS
DIM
ID	Stringa
MARCATOREDATA	Data
COLLEZIONEDATI	Collezione di classi
AZIONE	Azione
PREMODIFICA	Azione
POSTMODIFICA	Azione
PREMODIFICAGRIGLIA	Azione			28.1
POSTMODIFICAGRIGLIA	Azione			28.1
COLLEZIONECOLONNE	Collezione di classi			28.1
GRID
STACK
EXPANDER
DOCK
PERSONALIZZABILE	Intero
LINKTO

NOME

InteroInputObbligatorioValore non necessarioDesktopWebMobile

Consente di definire il nome del controllo.

RET

InputObbligatorioValore non necessarioDesktopWebMobile

Consente di definire le coordinate della cella del reticolo da associare al controllo, allo scopo di gestire gli spostamenti sulla videata.

POS

InputValore non necessarioDesktop

Consente di definire la posizione del controllo rispetto al contenitore.

DIM

InputValore non necessarioDesktopWebMobile

Dimensione del controllo.

Consente di indicare l'altezza e la larghezza. Per entrambi è possibile specificare l'unità di misura.

DIM[Altezza [UnitàMisura], Larghezza [UnitàMisura]]

note

L'unità di misura può essere: 'C' per il posizionamento a caratteri e 'P' per il posizionamento in pixel. L'indicazione è opzionale, se omesso si assume 'C' come default.

ID

StringaInputValore non necessarioDesktopWebMobile

Consente di definire l'identificativo univoco del controllo.

note

Viene utilizzato dall'ambiente per gestire le personalizzazioni effettuate durante l'esecuzione del programma.

MARCATOREDATA

DataInputValore non necessarioDesktopWebMobile

Consente di indicare una data specifica da evidenziare con una riga colorata lungo tutta l'altezza del diagramma di Gantt.

COLLEZIONEDATI

Collezione di classiValore non necessarioDesktop

Consente di definire i tasks da rappresentare.

AZIONE

AzioneInputValore non necessarioDesktop

SottoParametri

Consente di definire la callback richiamata quando viene eseguito un doppio click su un task.

PREMODIFICA

AzioneInputValore non necessarioDesktop

SottoParametri

Consente di definire la callback richiamata prima del salvataggio del dato modificato manualmente sulla collezione.

POSTMODIFICA

AzioneInputValore non necessarioDesktop

SottoParametri

Consente di definire la callback richiamata dopo il salvataggio del dato modificato manualmente sulla collezione.

PREMODIFICAGRIGLIA

28.1AzioneInputValore non necessarioDesktop

SottoParametri

Consente di definire la callback richiamata prima di riportare sulla collezione le modifiche apportate alla griglia del Gantt.

POSTMODIFICAGRIGLIA

28.1AzioneInputValore non necessarioDesktop

SottoParametri

Consente di definire la callback richiamata dopo aver riportato sulla collezione le modifiche apportate alla griglia del Gantt.

COLLEZIONECOLONNE

28.1Collezione di classiValore non necessarioDesktop

Consente di definire le colonne visualizzate all'interno della griglia.

GRID

InputValore non necessarioDesktop

SottoParametri

Consente di definire l'attached property riferita ad un pannello grid.

STACK

InputValore non necessarioDesktop

SottoParametri

Consente di definire l'attached property riferita ad un pannello stack.

EXPANDER

InputValore non necessarioDesktop

SottoParametri

Consente di definire l'attached property riferita ad un pannello expander.

DOCK

InputValore non necessarioDesktop

SottoParametri

Consente di indicare se il controllo deve occupare tutto lo spazio del DockPanel in verticale e/o in orizzontale.

PERSONALIZZABILE

InteroInputBinarioValore non necessarioDesktop

Consente di definire se il controllo grafico è personalizzabile dall'utente in fase di runtime.

Parametro con valori ammessi, si possono utilizzare i seguenti valori:

Valore	Descrizione
0	No
1	Si

LINKTO

InputValore non necessarioDesktop

SottoParametri

Consente di definire un legame tra due controlli esistenti all'interno della stessa videata.

Metodi

Metodo	Descrizione	SMP
Get_ChangedTask	Restituisce l'elemento riferito alla riga della griglia che è stato modificato
Get_ChangingTask	Restituisce l'elemento riferito alla riga della griglia che si sta per modificare
Get_Date	Restituisce la data su cui è stato posizionato il Gantt
Get_Elemento	Restituisce la classe riferita al task selezionata
Get_Zoom_Level	Restituisce il livello dello zoom
Set_Date	Sposta il Gantt alla data indicata
Set_Editable	Definisce qualecomponente del controllo grafico è editabile o meno
Set_Zoom	Aggiorna un set di tasks
Set_Zoom_Level	Imposta il livello dello zoom
UpdateTasks	Aggiorna un set di tasks

Esempi

Gantt di base

 '@DEFVID DIM[35,140] NOME[Videata] ID["IDVIDEATA"] TIT["Titolo Videata"]
 
    '@DEFGRIDPANEL NOME[GridPanel] ID["IDGridPanel"]   _
             RIGA[ALTEZZA[0.5] LAYOUT[#FISSO]]         _
             RIGA[ALTEZZA[34] LAYOUT[#FISSO]]          _
             RIGA[ALTEZZA[0.5] LAYOUT[#FISSO]]         _
             COLONNA[LUNGHEZZA[0.5] LAYOUT[#FISSO]]    _
             COLONNA[LUNGHEZZA[139] LAYOUT[#DINAMICO]] _
             COLONNA[LUNGHEZZA[0.5] LAYOUT[#FISSO]] 
             
       '@DEFGANTT NOME[GANTT] ID["IDGANTT"] POS[1,1] DIM[1,1] RET[1,1] _
                  COLLEZIONEDATI[CollezioneTask]    _
                  MARCATOREDATA[MarcatoreTemporale] _
                  GRID[COL[1] RIGA[1] COLDIN[1] RIGADIN[1]]
 
    '@ENDGRIDPANEL NOME[GridPanel]

 '@RUNVID

... 
'@SRP Load()

 GoSub InitGantt
 DefinizioneGantt()

Return

... 
'@SR InitGantt
       
 ' Pulizia variabili
 CollezioneTask.Clear()
 
 ' Definizione stili
 '@DEFSTYLE STILE["base"] COLORESFONDO[AZZURRO]
 '@DEFSTYLE STILE["completo"] COLORESFONDO[BLU]
 
 '@DEFSTYLE STILE["rosso"]       COLORESFONDO[ROSSO]
 '@DEFSTYLE STILE["giallo"]      COLORESFONDO[GIALLO]
 '@DEFSTYLE STILE["blu"]         COLORESFONDO[BLU]
 '@DEFSTYLE STILE["bordeaux"]    COLORESFONDO[BORDEAUX]
 '@DEFSTYLE STILE["viola"]       COLORESFONDO[VIOLA]
 '@DEFSTYLE STILE["grigio"]      COLORESFONDO[GRIGIOCHIARO]
 '@DEFSTYLE STILE["fucsia"]      COLORESFONDO[FUCSIA]
 '@DEFSTYLE STILE["verdelimone"] COLORESFONDO[VERDELIMONE]
 
 ' Definizione data di partenza
 Oggi = BCSystemInfo.GetDate()
 
 ' Definizione date di esempio
 OggiMenoQuattro = FNDAYDATEADD(Oggi,-4)
 OggiMenoDue     = FNDAYDATEADD(Oggi,-2)
 OggiPiuUno      = FNDAYDATEADD(Oggi,1) 
 OggiPiuDue      = FNDAYDATEADD(Oggi,2) 
 OggiPiuTre      = FNDAYDATEADD(Oggi,3) 
 OggiPiuQuattro  = FNDAYDATEADD(Oggi,4) 
 OggiPiuCinque   = FNDAYDATEADD(Oggi,5) 
 OggiPiuSei      = FNDAYDATEADD(Oggi,6) 
 OggiPiu24       = FNDAYDATEADD(Oggi,24)   
                                           
Return

... 
'@SRP DefinizioneGantt() 

  'Progetto 
   Task.Clear()
   Task.Id = "Progetto1"
   Task.IdPadre = ""
   Task.Task  = "Progetto #1"
   Task.DataInizio = Oggi 
   Task.DataFine = OggiPiuUno 
   Task.OraInizio = 800
   Task.OraFine = 1730
   Task.Completamento = 32
   Task.Durata  =  1
   Task.Tipologia = BCTD_GANTT_TYPE.Project
    
   'Collegamenti progetto 
   Task.AggiungiCollegamento("Task1_1", BCTD_GANTT_LINK_POSITION.DaInizioAInizio)
   Task.AggiungiCollegamento("Task1_2", BCTD_GANTT_LINK_POSITION.DaFineAInizio)     
   Task.AggiungiRisorsa(1,"Andrea")
   Task.AggiungiMarker("Marker1", BCTD_GANTT_MARKER.PARTIAL, OggiPiuDue, 1830)
   Task.AggiungiMarker("Marker2", BCTD_GANTT_MARKER.TERMINATE, OggiPiuQuattro, 830)
   
   CollezioneTask.AggiungiTask(Task [INOUT])
         
   'Milestone
   CollezioneTask.AggiungiMilestone("Milestone1","Progetto3","milestone #1",OggiPiuQuattro,830,"","",0)
   
   'Task 1 progetto 1
   Task.Clear()
   Task.Id = "Task1_1"
   Task.IdPadre = "Progetto1"
   Task.Task  = "Task #1_1"
   Task.DataInizio = OggiMenoQuattro
   Task.DataFine = OggiPiuDue
   Task.OraInizio = 800
   Task.OraFine = 1730
   Task.Completamento = 80
   Task.Tipologia = BCTD_GANTT_TYPE.Task
   Task.Colore = "base"
   Task.ColoreCompletamento = "completo"
   Task.Durata = 6
   Task.AggiungiRisorsa(8,"Giulia")
   Task.AggiungiMarker("Marker1",BCTD_GANTT_MARKER.PARTIAL,Oggi,1830)
   Task.AggiungiMarker("Marker2",BCTD_GANTT_MARKER.PARTIAL,OggiMenoDue,1830)
   Task.AggiungiMarker("m3",BCTD_GANTT_MARKER.PARTIAL,OggiPiuUno,1830)
   Task.AggiungiMarker("m4",BCTD_GANTT_MARKER.TERMINATE,OggiPiuTre,830)
   CollezioneTask.AggiungiTask(Task [INOUT])
   MarcatoreTemporale  =  OggiPiuDue ' Data evidenziata con una riga lunga tutta l'altelzza del diagramma
   
   'Task 2 progetto 1
   Task.Clear()
   Task.Id = "Task1_2"
   Task.IdPadre = "Progetto1"
   Task.Task  = "Task #1_2"
   Task.DataInizio = OggiMenoQuattro
   Task.DataFine = OggiPiuDue
   Task.OraInizio = 800
   Task.OraFine = 1730
   Task.Completamento = 80
   Task.Tipologia = BCTD_GANTT_TYPE.Task
   Task.Colore = "base"
   Task.ColoreCompletamento = "completo"
   Task.Durata = 8
   Task.AggiungiRisorsa(8,"Piero")
   Task.AggiungiMarker("Marker1",BCTD_GANTT_MARKER.PARTIAL,Oggi,1830)
   Task.AggiungiMarker("Marker2",BCTD_GANTT_MARKER.PARTIAL,OggiMenoDue,1830)
   Task.AggiungiMarker("m3",BCTD_GANTT_MARKER.PARTIAL,OggiPiuUno,1830)
   Task.AggiungiMarker("m4",BCTD_GANTT_MARKER.TERMINATE,OggiPiuTre,830)
   CollezioneTask.AggiungiTask(Task [INOUT])
   MarcatoreTemporale = OggiPiuTre ' Data evidenziata con una riga lunga tutta l'altelzza del diagramma
    
Return

Link con griglia da collezione

 '@DEFVID DIM[30,130] NOME[VideataGanttLink] ID["IDVIDEATA"] TIT["Titolo Videata"]

 ' Inserimento dello splitter per separare la griglia da collezione dal Gantt
 '@DEFGRIDPANEL NOME[GridPanelGanttLink] TIT["Gantt"] ID["GridGantt"]_
                LAYOUTTIT[STILE[#INTESTAZIONE_VIDEATA] ]_
                COLONNA[LUNGHEZZA[69.5] LAYOUT[#DINAMICO]] _
                COLONNA[LUNGHEZZA[60] LAYOUT[#DINAMICO]] _
                RIGA[ALTEZZA[28] LAYOUT[#DINAMICO]] _
                SPLITTER[COLONNA[1]]

    ' Associazione tra griglia da collezione e  Gantt
    ' LINKTO["IDGANTT"] permette di associare la griglia da collezione al Gantt
    '@DEFCOLLECTIONGRID NOME[GrigliaGantt] ID["GrigliaGantt"] RET[1,1] POS[1,1] DIM[1,1] _
                        COLLEZIONEDATI[CollezioneDati] OGGETTOCORRENTE[CurrTask] COLLEZIONECOLONNE[Colonne] _
                        VALIDAZIONEDATI[GES[CurrTask.Valida(VideataGanttLink.GetProprietaCorrente())] _
                        DERIVAZIONEDATI[CurrTask.Deriva_dati(VideataGanttLink.GetProprietaCorrente())]] _
                        INRIGA[IngressoRiga()] _
                        OUTRIGA[OutRiga()]_
                        LINKTO[ID["IDGANTT"]] _
                        GRID[COL[1] RIGA[1] COLDIN[1] RIGADIN[1]]

    ' Il parametro COLLEZIONEDATI non è presente, perchè sostituito dal parametro LINKTO della Griglia
    '@DEFGANTT NOME[VidGantt] ID["IDGANTT"] POS[1,1] DIM[1,1] RET[1,1] _
               GRID[COL[2] RIGA[1] COLDIN[1] RIGADIN[1]] _
               AZIONE[DefinisciRisorse()] _
               POSTMODIFICA[PostModifica()] _
               MARCATOREDATA[MarcatoreTemporale] 

 '@ENDGRIDPANEL NOME[GridPanelGanttLink]

'@RUNVID

... 
'@SRP Load1() 

 DefinizioneColonne()

Return

... 
'@SRP DefinizioneColonne()

 ' Definizione colonna su cui impostare l'alberatura
 Colonna.Clear()
 Colonna.Init("Task",20,1,0,0,0)
 Colonna.AbilitaCellaAlberata=#TRUE
 Colonne.AggiungiColonna(Colonna [INOUT])

 ' Definizione altre colonne
 Colonna.Clear() :Colonna.Init("DataInizio",15,2,0,0,0)      :Colonna.Titolo="Data Inizio"                        :Colonne.AggiungiColonna(Colonna [INOUT])
 Colonna.Clear() :Colonna.Init("OraInizio",10,3,0,0,0)       :Colonna.Titolo="Ora Inizio"  :Colonna.Formato="Ora" :Colonne.AggiungiColonna(Colonna [INOUT])
 Colonna.Clear() :Colonna.Init("DataFine",15,4,0,0,0)        :Colonna.Titolo="Data Fine"                          :Colonne.AggiungiColonna(Colonna [INOUT])
 Colonna.Clear() :Colonna.Init("OraFine",10,5,0,0,0)         :Colonna.Titolo="Ora Fine"    :Colonna.Formato="Ora" :Colonne.AggiungiColonna(Colonna [INOUT])
 Colonna.Clear() :Colonna.Init("Completamento",10,6,0,0,0)   :Colonna.Titolo="Completamento (%)"                  :Colonne.AggiungiColonna(Colonna [INOUT])
 Colonna.Clear() :Colonna.Init("Durata",10,7,0,0,1)          :Colonna.Titolo="Durata (giorni)"                    :Colonne.AggiungiColonna(Colonna [INOUT])
 Colonna.Clear() :Colonna.Init("DataVariazione",10,8,0,0,1)  :Colonna.Titolo="Data variazione"                    :Colonne.AggiungiColonna(Colonna [INOUT])
 Colonna.Clear() :Colonna.Init("OperVariazione",10,9,0,0,1)  :Colonna.Titolo="Oper. variazione"                   :Colonne.AggiungiColonna(Colonna [INOUT])
 Colonna.Clear() :Colonna.Init("Nota",15,10,0,0,0)           :Colonna.Titolo="Annotazione"                        :Colonne.AggiungiColonna(Colonna [INOUT])

Return

... 
'@SRP IngressoRiga()
Return

... 
'@SRP OutRiga()
Return

... 
'@SRP DefinisciRisorse()
Return

... 
'@SRP PostModifica()
Return